first commit

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example1_EnableRTCM/Example1_EnableRTCM.ino

@@ -0,0 +1,77 @@
+/*
+  Send UBX binary commands to enable RTCM sentences on u-blox NEO-M8P module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: September 7th, 2018
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example sends the command to enable the four RTCM messages needed for RTK. This 
+  is the first part of a larger tutorial and example to setup an RTK base station.
+  These commands are only accepted by the NEO-M8P module.
+ 
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+void setup()
+{
+  Serial.begin(115200);
+  while(!Serial); //Wait for user to open terminal
+  Serial.println(F("u-blox RTCM Enable Example"));
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGNSS.begin() == false) //Connect to the u-blox module using Wire port
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  while(Serial.available()) Serial.read(); //Clear any latent chars in serial buffer
+  Serial.println(F("Press any key to send commands to enable RTCM 3.x"));
+  while(Serial.available() == 0) ; //Wait for user to press a key
+
+  myGNSS.setI2COutput(COM_TYPE_UBX | COM_TYPE_NMEA | COM_TYPE_RTCM3); // Ensure RTCM3 is enabled
+  myGNSS.saveConfiguration(); //Save the current settings to flash and BBR
+
+  bool response = true;
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1005, COM_PORT_I2C, 1); //Enable message 1005 to output through I2C port, message every second
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1077, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1087, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1230, COM_PORT_I2C, 10); //Enable message every 10 seconds
+
+  if (response == true)
+  {
+    Serial.println(F("RTCM messages enabled"));
+  }
+  else
+  {
+    Serial.println(F("RTCM failed to enable. Are you sure you have an NEO-M8P?"));
+    while(1); //Freeze
+  }
+
+  //RTCM is now enabled but we haven't done a 'survey-in'
+  //See example 4 for the full Base RTK setup
+}
+
+void loop()
+{
+  myGNSS.checkUblox(); //See if new data is available. Process bytes as they come in.
+
+  delay(250); //Don't pound too hard on the I2C bus
+}

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example2_StartRTCMBase/Example2_StartRTCMBase.ino

@@ -0,0 +1,164 @@
+/*
+  Note: compiles OK with v2.0 but is currently untested
+  
+  Send UBX binary commands to enable RTCM sentences on u-blox NEO-M8P-2 module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: September 7th, 2018
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example does all steps to configure and enable a NEO-M8P-2 as a base station:
+    Begin Survey-In
+    Once we've achieved 2m accuracy and 300s have passed, survey is complete
+    Enable four RTCM messages
+    Begin outputting RTCM bytes
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println(F("u-blox NEO-M8P-2 base station example"));
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGNSS.begin() == false) //Connect to the u-blox module using Wire port
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  myGNSS.setI2COutput(COM_TYPE_UBX | COM_TYPE_NMEA | COM_TYPE_RTCM3); // Ensure RTCM3 is enabled
+  myGNSS.saveConfiguration(); //Save the current settings to flash and BBR
+
+  while (Serial.available()) Serial.read(); //Clear any latent chars in serial buffer
+  Serial.println(F("Press any key to send commands to begin Survey-In"));
+  while (Serial.available() == 0) ; //Wait for user to press a key
+
+  bool response;
+
+  //Check if Survey is in Progress before initiating one
+  // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+  // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+  // You can either read the data from packetUBXNAVSVIN directly
+  // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+  response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (request can take a long time)
+  
+  if (response == false) // Check if fresh data was received
+  {
+    Serial.println(F("Failed to get Survey In status. Freezing..."));
+    while (1); //Freeze
+  }
+
+  if (myGNSS.getSurveyInActive() == true) // Use the helper function
+  {
+    Serial.print(F("Survey already in progress."));
+  }
+  else
+  {
+    //Start survey
+    response = myGNSS.enableSurveyMode(300, 2.000); //Enable Survey in, 300 seconds, 2.0m
+    if (response == false)
+    {
+      Serial.println(F("Survey start failed. Freezing..."));
+      while (1);
+    }
+    Serial.println(F("Survey started. This will run until 300s has passed and less than 2m accuracy is achieved."));
+  }
+
+  while(Serial.available()) Serial.read(); //Clear buffer
+  
+  //Begin waiting for survey to complete
+  while (myGNSS.getSurveyInValid() == false) // Call the helper function
+  {
+    if(Serial.available())
+    {
+      byte incoming = Serial.read();
+      if(incoming == 'x')
+      {
+        //Stop survey mode
+        response = myGNSS.disableSurveyMode(); //Disable survey
+        Serial.println(F("Survey stopped"));
+        break;
+      }
+    }
+    
+    // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+    // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+    // You can either read the data from packetUBXNAVSVIN directly
+    // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+    response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (req can take a long time)
+    if (response == true) // Check if fresh data was received
+    {
+      Serial.print(F("Press x to end survey - "));
+      Serial.print(F("Time elapsed: "));
+      Serial.print((String)myGNSS.getSurveyInObservationTime());
+
+      Serial.print(F(" Accuracy: "));
+      Serial.print((String)myGNSS.getSurveyInMeanAccuracy());
+      Serial.println();
+    }
+    else
+    {
+      Serial.println(F("SVIN request failed"));
+    }
+
+    delay(1000);
+  }
+  Serial.println(F("Survey valid!"));
+
+  response = true;
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1005, COM_PORT_I2C, 1); //Enable message 1005 to output through I2C port, message every second
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1077, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1087, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1230, COM_PORT_I2C, 10); //Enable message every 10 seconds
+
+  if (response == true)
+  {
+    Serial.println(F("RTCM messages enabled"));
+  }
+  else
+  {
+    Serial.println(F("RTCM failed to enable. Are you sure you have an NEO-M8P?"));
+    while (1); //Freeze
+  }
+
+  Serial.println(F("Base survey complete! RTCM now broadcasting."));
+}
+
+void loop()
+{
+  myGNSS.checkUblox(); //See if new data is available. Process bytes as they come in.
+
+  delay(250); //Don't pound too hard on the I2C bus
+}
+
+//This function gets called from the SparkFun u-blox Arduino Library.
+//As each RTCM byte comes in you can specify what to do with it
+//Useful for passing the RTCM correction data to a radio, Ntrip broadcaster, etc.
+void SFE_UBLOX_GNSS::processRTCM(uint8_t incoming)
+{
+  //Let's just pretty-print the HEX values for now
+  if (myGNSS.rtcmFrameCounter % 16 == 0) Serial.println();
+  Serial.print(F(" "));
+  if (incoming < 0x10) Serial.print(F("0"));
+  Serial.print(incoming, HEX);
+}

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example2_StartRTCMBase_virtual/Example2_StartRTCMBase_virtual.ino

@@ -0,0 +1,168 @@
+/*
+  Note: compiles OK with v2.0 but is currently untested
+
+  Send UBX binary commands to enable RTCM sentences on u-blox NEO-M8P-2 module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: September 7th, 2018
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example does all steps to configure and enable a NEO-M8P-2 as a base station:
+    Begin Survey-In
+    Once we've achieved 2m accuracy and 300s have passed, survey is complete
+    Enable four RTCM messages
+    Begin outputting RTCM bytes
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+
+class MY_SFE_UBLOX_GNSS : public SFE_UBLOX_GNSS
+{
+  //This function gets called from the SparkFun u-blox Arduino Library.
+  //As each RTCM byte comes in you can specify what to do with it
+  //Useful for passing the RTCM correction data to a radio, Ntrip broadcaster, etc.
+  virtual void processRTCM_v(uint8_t incoming)
+  {
+    //Let's just pretty-print the HEX values for now
+    if (rtcmFrameCounter % 16 == 0) Serial.println();
+    Serial.print(F(" "));
+    if (incoming < 0x10) Serial.print(F("0"));
+    Serial.print(incoming, HEX);
+  }
+};
+
+MY_SFE_UBLOX_GNSS myGNSS;
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println(F("u-blox NEO-M8P-2 base station example"));
+
+  Wire.begin();
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  if (myGNSS.begin() == false) //Connect to the u-blox module using Wire port
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring. Freezing."));
+    while (1);
+  }
+
+  myGNSS.setI2COutput(COM_TYPE_UBX | COM_TYPE_NMEA | COM_TYPE_RTCM3); // Ensure RTCM3 is enabled
+  myGNSS.saveConfiguration(); //Save the current settings to flash and BBR
+
+  while (Serial.available()) Serial.read(); //Clear any latent chars in serial buffer
+  Serial.println(F("Press any key to send commands to begin Survey-In"));
+  while (Serial.available() == 0) ; //Wait for user to press a key
+
+  bool response;
+
+  //Check if Survey is in Progress before initiating one
+  // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+  // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+  // You can either read the data from packetUBXNAVSVIN directly
+  // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+  response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (request can take a long time)
+
+  if (response == false) // Check if fresh data was received
+  {
+    Serial.println(F("Failed to get Survey In status. Freezing..."));
+    while (1); //Freeze
+  }
+
+  if (myGNSS.getSurveyInActive() == true) // Use the helper function
+  {
+    Serial.print(F("Survey already in progress."));
+  }
+  else
+  {
+    //Start survey
+    response = myGNSS.enableSurveyMode(300, 2.000); //Enable Survey in, 300 seconds, 2.0m
+    if (response == false)
+    {
+      Serial.println(F("Survey start failed. Freezing..."));
+      while (1);
+    }
+    Serial.println(F("Survey started. This will run until 300s has passed and less than 2m accuracy is achieved."));
+  }
+
+  while(Serial.available()) Serial.read(); //Clear buffer
+
+  //Begin waiting for survey to complete
+  while (myGNSS.getSurveyInValid() == false) // Call the helper function
+  {
+    if(Serial.available())
+    {
+      byte incoming = Serial.read();
+      if(incoming == 'x')
+      {
+        //Stop survey mode
+        response = myGNSS.disableSurveyMode(); //Disable survey
+        Serial.println(F("Survey stopped"));
+        break;
+      }
+    }
+
+    // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+    // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+    // You can either read the data from packetUBXNAVSVIN directly
+    // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+    response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (req can take a long time)
+    if (response == true) // Check if fresh data was received
+    {
+      Serial.print(F("Press x to end survey - "));
+      Serial.print(F("Time elapsed: "));
+      Serial.print((String)myGNSS.getSurveyInObservationTime());
+
+      Serial.print(F(" Accuracy: "));
+      Serial.print((String)myGNSS.getSurveyInMeanAccuracy());
+      Serial.println();
+    }
+    else
+    {
+      Serial.println(F("SVIN request failed"));
+    }
+
+    delay(1000);
+  }
+  Serial.println(F("Survey valid!"));
+
+  response = true;
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1005, COM_PORT_I2C, 1); //Enable message 1005 to output through I2C port, message every second
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1077, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1087, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1230, COM_PORT_I2C, 10); //Enable message every 10 seconds
+
+  if (response == true)
+  {
+    Serial.println(F("RTCM messages enabled"));
+  }
+  else
+  {
+    Serial.println(F("RTCM failed to enable. Are you sure you have an NEO-M8P?"));
+    while (1); //Freeze
+  }
+
+  Serial.println(F("Base survey complete! RTCM now broadcasting."));
+}
+
+void loop()
+{
+  myGNSS.checkUblox(); //See if new data is available. Process bytes as they come in.
+
+  delay(250); //Don't pound too hard on the I2C bus
+}

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example3_BaseWithLCD/Example3_BaseWithLCD.ino

@@ -0,0 +1,198 @@
+/*
+  Note: compiles OK with v2.0 but is currently untested
+  
+  Send UBX binary commands to enable RTCM sentences on u-blox NEO-M8P-2 module
+  By: Nathan Seidle
+  SparkFun Electronics
+  Date: September 7th, 2018
+  License: MIT. See license file for more information but you can
+  basically do whatever you want with this code.
+
+  This example does all steps to configure and enable a NEO-M8P-2 as a base station:
+    Begin Survey-In
+    Once we've achieved 2m accuracy and 300s have passed, survey is complete
+    Enable four RTCM messages
+    Begin outputting RTCM bytes
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  ZED-F9P RTK2: https://www.sparkfun.com/products/15136
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+  SAM-M8Q: https://www.sparkfun.com/products/15106
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a BlackBoard
+  Plug a SerLCD onto the Qwiic bus
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Watch the output on the LCD or open the serial monitor at 115200 baud to see the output
+*/
+
+#define STAT_LED 13
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //Click here to get the library: http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+#include <SerLCD.h> //Click here to get the library: http://librarymanager/All#SparkFun_SerLCD
+SerLCD lcd; // Initialize the library with default I2C address 0x72
+
+void setup()
+{
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println(F("u-blox GNSS I2C Test"));
+
+  Wire.begin();
+
+  pinMode(STAT_LED, OUTPUT);
+  digitalWrite(STAT_LED, LOW);
+
+  lcd.begin(Wire); //Set up the LCD for Serial communication at 9600bps
+  lcd.setBacklight(0x4B0082); //indigo, a kind of dark purplish blue
+  lcd.clear();
+  lcd.print(F("LCD Ready"));
+
+  myGNSS.begin(Wire);
+  if (myGNSS.isConnected() == false)
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring. Freezing."));
+    lcd.setCursor(0, 1);
+    lcd.print(F("No GNSS detected"));
+    while (1);
+  }
+
+  Wire.setClock(400000); //Increase I2C clock speed to 400kHz
+
+  lcd.setCursor(0, 1);
+  lcd.print("GNSS Detected");
+
+  myGNSS.setI2COutput(COM_TYPE_UBX | COM_TYPE_NMEA | COM_TYPE_RTCM3); // Ensure RTCM3 is enabled
+  myGNSS.saveConfiguration(); //Save the current settings to flash and BBR
+
+  //Check if Survey is in Progress before initiating one
+  // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+  // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+  // You can either read the data from packetUBXNAVSVIN directly
+  // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+  bool response;
+  response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (request can take a long time)
+  if (response == false)
+  {
+    Serial.println(F("Failed to get Survey In status"));
+    while (1); //Freeze
+  }
+
+  if (myGNSS.getSurveyInActive() == true) // Use the helper function
+  {
+    Serial.print(F("Survey already in progress."));
+    lcd.setCursor(0, 2);
+    lcd.print(F("Survey already going"));
+  }
+  else
+  {
+    //Start survey
+    response = myGNSS.enableSurveyMode(300, 2.000); //Enable Survey in, 300 seconds, 2.0m
+    if (response == false)
+    {
+      Serial.println(F("Survey start failed"));
+      lcd.setCursor(0, 3);
+      lcd.print(F("Survey start failed"));
+      while (1);
+    }
+    Serial.println(F("Survey started. This will run until 300s has passed and less than 2m accuracy is achieved."));
+  }
+
+  while (Serial.available()) Serial.read(); //Clear buffer
+
+  lcd.clear();
+  lcd.print(F("Survey in progress"));
+
+  //Begin waiting for survey to complete
+  while (myGNSS.getSurveyInValid() == false) // Call the helper function
+  {
+    if (Serial.available())
+    {
+      byte incoming = Serial.read();
+      if (incoming == 'x')
+      {
+        //Stop survey mode
+        response = myGNSS.disableSurveyMode(); //Disable survey
+        Serial.println(F("Survey stopped"));
+        break;
+      }
+    }
+
+    // From v2.0, the data from getSurveyStatus (UBX-NAV-SVIN) is returned in UBX_NAV_SVIN_t packetUBXNAVSVIN
+    // Please see u-blox_structs.h for the full definition of UBX_NAV_SVIN_t
+    // You can either read the data from packetUBXNAVSVIN directly
+    // or can use the helper functions: getSurveyInActive; getSurveyInValid; getSurveyInObservationTime; and getSurveyInMeanAccuracy
+    response = myGNSS.getSurveyStatus(2000); //Query module for SVIN status with 2000ms timeout (req can take a long time)
+    if (response == true)
+    {
+      Serial.print(F("Press x to end survey - "));
+      Serial.print(F("Time elapsed: "));
+      Serial.print((String)myGNSS.getSurveyInObservationTime());
+
+      lcd.setCursor(0, 1);
+      lcd.print(F("Elapsed: "));
+      lcd.print((String)myGNSS.getSurveyInObservationTime());
+
+      Serial.print(F(" Accuracy: "));
+      Serial.print((String)myGNSS.getSurveyInMeanAccuracy());
+      Serial.println();
+
+      lcd.setCursor(0, 2);
+      lcd.print(F("Accuracy: "));
+      lcd.print((String)myGNSS.getSurveyInMeanAccuracy());
+    }
+    else
+    {
+      Serial.println(F("SVIN request failed"));
+    }
+
+    delay(1000);
+  }
+  Serial.println(F("Survey valid!"));
+
+  response = true;
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1005, COM_PORT_I2C, 1); //Enable message 1005 to output through I2C port, message every second
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1077, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1087, COM_PORT_I2C, 1);
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1230, COM_PORT_I2C, 10); //Enable message every 10 seconds
+
+  if (response == true)
+  {
+    Serial.println(F("RTCM messages enabled"));
+  }
+  else
+  {
+    Serial.println(F("RTCM failed to enable. Are you sure you have an NEO-M8P?"));
+    while (1); //Freeze
+  }
+
+  Serial.println(F("Base survey complete! RTCM now broadcasting."));
+  lcd.clear();
+  lcd.print(F("Transmitting RTCM"));
+}
+
+void loop()
+{
+  myGNSS.checkUblox(); //See if new data is available. Process bytes as they come in.
+
+  //Do anything you want. Call checkUblox() every second. NEO-M8P-2 has TX buffer of 4k bytes.
+  
+  delay(250); //Don't pound too hard on the I2C bus
+}
+
+//This function gets called from the SparkFun u-blox Arduino Library.
+//As each RTCM byte comes in you can specify what to do with it
+//Useful for passing the RTCM correction data to a radio, Ntrip broadcaster, etc.
+void SFE_UBLOX_GNSS::processRTCM(uint8_t incoming)
+{
+  //Let's just pretty-print the HEX values for now
+  if (myGNSS.rtcmFrameCounter % 16 == 0) Serial.println();
+  Serial.print(" ");
+  if (incoming < 0x10) Serial.print("0");
+  Serial.print(incoming, HEX);
+}

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example4_MovingBase_Base/Example4_MovingBase_Base.ino

@@ -0,0 +1,74 @@
+/*
+  Configure the NEO-M8P-2 as a "moving base"
+  By: Paul Clark
+  SparkFun Electronics
+  Date: March 20th, 2023
+  License: MIT. See license file for more information.
+
+  This example configures the NEO-M8P-2 as a moving base.
+  It will output RTCM3 1077, 1087, 1230 and 4072.0 messages on UART1.
+  Connect UART1 TX to UART1 RX on a NEO-M8P rover. Also connect GND to GND.
+  The next example shows how to display the relative position of the rover.
+ 
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Connect UART1 TX to UART1 RX on a NEO-M8P rover. Also connect GND to GND.
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+void setup()
+{
+  delay(1000);
+  
+  Serial.begin(115200);
+  while(!Serial); //Wait for user to open terminal
+  Serial.println(F("u-blox NEO-M8P Moving Base Example"));
+
+  Wire.begin();
+
+  while (myGNSS.begin() == false) //Connect to the u-blox module using Wire port
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring."));
+  }
+
+  // Uncomment the next line if you want to reset your module back to the default settings with 1Hz navigation rate
+  //myGNSS.factoryDefault(); delay(5000);
+
+  myGNSS.setUART1Output(COM_TYPE_RTCM3); // Configure UART1 to output RTCM3 only. Disable NMEA.
+  myGNSS.saveConfiguration(); //Save the current settings to flash and BBR
+
+  bool response = true;
+  
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1077, COM_PORT_UART1, 1); //Enable message 1077 on UART1
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1087, COM_PORT_UART1, 1); //Enable message 1087 on UART1
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_1230, COM_PORT_UART1, 1); //Enable message 1230 on UART1
+  response &= myGNSS.enableRTCMmessage(UBX_RTCM_4072_0, COM_PORT_UART1, 1); //Enable message 4072.0 on UART1
+  
+  response &= myGNSS.disableSurveyMode(); //Essential - we need to set TMODE3 to Disabled to allow 4072.0 to be output
+
+  if (response == true)
+  {
+    Serial.println(F("RTCM messages enabled"));
+  }
+  else
+  {
+    Serial.println(F("RTCM failed to enable. Are you sure you have an NEO-M8P?"));
+  }
+}
+
+void loop()
+{
+  myGNSS.checkUblox(); //See if new data is available. Process bytes as they come in.
+
+  delay(250); //Don't pound too hard on the I2C bus
+}

libraries/SparkFun_u-blox_GNSS_Arduino_Library/examples/NEO-M8P-2/Example5_MovingBase_Rover/Example5_MovingBase_Rover.ino

@@ -0,0 +1,117 @@
+/*
+  Display the relative position of a NEO-M8P-2 rover
+  By: Paul Clark
+  SparkFun Electronics
+  Date: March 20th, 2023
+  License: MIT. See license file for more information.
+
+  This example shows how to query the module for RELPOS information in the NED frame.
+  It assumes you already have RTCM correction data being fed to the receiver on UART1.
+  Connect UART1 TX on the base to UART1 RX on the rover. Also connect GND to GND.
+
+  Feel like supporting open source hardware?
+  Buy a board from SparkFun!
+  NEO-M8P RTK: https://www.sparkfun.com/products/15005
+
+  Hardware Connections:
+  Plug a Qwiic cable into the GNSS and a RedBoard Qwiic or BlackBoard
+  If you don't have a platform with a Qwiic connection use the SparkFun Qwiic Breadboard Jumper (https://www.sparkfun.com/products/14425)
+  Connect UART1 TX on the base to UART1 RX on the rover. Also connect GND to GND.
+  Open the serial monitor at 115200 baud to see the output
+*/
+
+#include <Wire.h> //Needed for I2C to GNSS
+
+#include <SparkFun_u-blox_GNSS_Arduino_Library.h> //http://librarymanager/All#SparkFun_u-blox_GNSS
+SFE_UBLOX_GNSS myGNSS;
+
+void setup()
+{
+  delay(1000);
+  
+  Serial.begin(115200);
+  while (!Serial); //Wait for user to open terminal
+  Serial.println("u-blox NEO-M8P Rover Example");
+
+  Wire.begin();
+
+  while (myGNSS.begin() == false) //Connect to the u-blox module using Wire port
+  {
+    Serial.println(F("u-blox GNSS not detected at default I2C address. Please check wiring."));
+  }
+
+  // Uncomment the next line if you want to reset your module back to the default settings with 1Hz navigation rate
+  //myGNSS.factoryDefault(); delay(5000);
+
+  // By default, UART1 Protocol In is set to NMEA + UBX + RTCM3. No changes are necessary. But we can manually configure the port if required.
+  Serial.print(myGNSS.setPortInput(COM_PORT_UART1, COM_TYPE_UBX | COM_TYPE_RTCM3)); //Enable UBX and RTCM3 input on UART1
+  myGNSS.saveConfigSelective(VAL_CFG_SUBSEC_IOPORT); //Save the communications port settings to flash and BBR
+}
+
+void loop()
+{
+  // The data from getRELPOSNED (UBX-NAV-RELPOSNED) is returned in UBX_NAV_RELPOSNED_t packetUBXNAVRELPOSNED
+  // Please see u-blox_structs.h for the full definition of UBX_NAV_RELPOSNED_t
+  // You can either read the data from packetUBXNAVRELPOSNED directly
+  // or can use the helper functions: getRelPosN/E/D; getRelPosAccN/E/D
+  // Note that NEO-M8P RELPOSNED is different to ZED-F9P. It does not contain the relative length and heading.
+  if (myGNSS.getRELPOSNED() == true)
+  {
+    Serial.print("relPosN: ");
+    Serial.println(myGNSS.getRelPosN(), 4); // Use the helper functions to get the rel. pos. as m
+    Serial.print("relPosE: ");
+    Serial.println(myGNSS.getRelPosE(), 4);
+    Serial.print("relPosD: ");
+    Serial.println(myGNSS.getRelPosD(), 4);
+
+    Serial.print("relPosHPN: ");
+    Serial.println((float)myGNSS.packetUBXNAVRELPOSNED->data.relPosHPN / 10, 1); //High-precision component. Convert to mm
+    Serial.print("relPosHPE: ");
+    Serial.println((float)myGNSS.packetUBXNAVRELPOSNED->data.relPosHPE / 10, 1);
+    Serial.print("relPosHPD: ");
+    Serial.println((float)myGNSS.packetUBXNAVRELPOSNED->data.relPosHPD / 10, 1);
+
+    Serial.print("accN: ");
+    Serial.println(myGNSS.getRelPosAccN(), 4); // Use the helper functions to get the rel. pos. accuracy as m
+    Serial.print("accE: ");
+    Serial.println(myGNSS.getRelPosAccE(), 4);
+    Serial.print("accD: ");
+    Serial.println(myGNSS.getRelPosAccD(), 4);
+
+    Serial.print("gnssFixOk: ");
+    if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.gnssFixOK == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("diffSolution: ");
+    if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.diffSoln == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("relPosValid: ");
+    if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.relPosValid == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+
+    Serial.print("carrier Solution Type: ");
+    if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.carrSoln == 0)
+      Serial.println("None");
+    else if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.carrSoln == 1)
+      Serial.println("Float");
+    else if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.carrSoln == 2)
+      Serial.println("Fixed");
+
+    Serial.print("isMoving: ");
+    if (myGNSS.packetUBXNAVRELPOSNED->data.flags.bits.isMoving == true)
+      Serial.println("x");
+    else
+      Serial.println("");
+  }
+  else
+    Serial.println("RELPOS request failed");
+
+  Serial.println("");
+}